[배치파일] 웹사이트 주기적 화면캡쳐 (공개 플그램이용)

컴터/기타 2009.08.12 00:17
설명
......
따라서 포털의 첫 화면과 뉴스홈의 보도배열 전자기록도 6개월동안 보관해야 하는 의무가 부과됐고, 보관 내용에는 기사제목과 제공 언론사, 배열위치, 처음으로 노출된 시각과 삭제된 시각이 포함돼야 한다.

이 같은 전자기록 보관 의무는 전년도 말을 기준으로 이전 3개월 일일 평균 이용자수가 10만명 이상인 사업자에게만 부여됐으며, 앞으로 제도 시행 결과에 따라 그 범위를 점차 확대한다는 계획이다.
......
http://www.cctoday.co.kr/news/articleView.html?idxno=426673

나중에 확대될 범위에 대비해 공개된 화면 캡쳐 플그램에 배치 파일을 얹혀 보았습니다.
필요하신분에게 도움 되었으면 하네요 (필요없을라나 ㅡㅡ;)

IECapt.exe 이용 하였으며, 더 많은 정보는 http://iecapt.sourceforge.net/ 로,,
시작은 start.bat 파일 실행하면 됩니다.





파랑색은 주석입니다.
--------------------------------- 배치 스크립트 설명 ---------------------------------

@echo off

:first
    rem sleep.exe 와 IECapt.exe 파일이 같은 위치에 있어야 하며 위치가 다를 경우 아래 set EXE=IECapt.exe와 set SAVEDIR=Capture/ 에서 수정.
    rem 이때 주의할 사항은 SAVEDIR=Capture/ 와 같이 '=' 사이를 띄우면 안됩니다. 공백까지 같이 인식함.
    rem 여기서 sleep.exe 는 delay를 주기위해 사용되는 것인데, 아마 ms windows 어느 버전인지는 모르지만 그 버전 부터는 있다고 합니다.
    rem 혹여 없는 분들을 위해 동봉했습니다.
    rem 그리고 IECapt.exe 파일은 http://iecapt.sourceforge.net/ 에서 공개한 프르그램이며 소스도 공개한 것으로 알고 있습니다.

    if not exist sleep.exe (
        echo sleep.exe 이라는 파일이 없습니다. 같은 폴더에 위치하여야 합니다.
        pause
        goto first
    )
    if not exist IECapt.exe (
        echo IECapt.exe 이라는 파일이 없습니다. 같은 폴더에 위치하여야 합니다.
        pause
        goto first
    )

    rem 시작프로그램에 등록 하거나 묻고 싶지 않을때는 아래 두줄 삭제해주세요.
    echo 시작할까요?
    pause
   
   
    :execute

        rem 캡쳐할 주기 입니다. 단위는 초(second) 이고 캡쳐하는데 약 5초정도 걸리니 1분(60초)마다 캡쳐받는다고 보면 됩니다.
        rem 캡쳐하는데 걸리는 시간은 PC마다 다르니 테스트후 설정하세요.
        rem URL : 캡쳐할 홈페이지, EXE : IECapt.exe의 파일 경로, SAVEDIR : 캡쳐받은 파일 저장 장소. 년/월/일/시간_분.png 이렇게 디렉토리가 생성됩니다.

        set T=55
        set URL=홈페이지URL(예:http://daum.net)
        set EXE=IECapt.exe
        set SAVEDIR=Capture\

        set Y=%date:~0,4%
        set M=%date:~5,2%
        set D=%date:~8,2%
        set S=
        if "%time:~0,1%"==" " (set S=%time:~1,1%_%time:~3,2%) else (set S=%time:~0,2%_%time:~3,2%)

       
        rem create directory
        if not exist %SAVEDIR%%Y%        md %SAVEDIR%%Y%
        if not exist %SAVEDIR%%Y%\%M%        md %SAVEDIR%%Y%\%M%
        if not exist %SAVEDIR%%Y%\%M%\%D%    md %SAVEDIR%%Y%\%M%\%D%


        %EXE% --min-width=1000 --url=%URL% --out=%SAVEDIR%%Y%\%M%\%D%\%S%.png

       
        rem print infomation
        echo Save File %SAVEDIR%%Y%\%M%\%D%\%S%.png
        echo Wating %T% Seconds For %URL% Capture ...
       

        sleep.exe %T%

        set Y=
        set M=
        set D=
        set S=

        set T=
        set URL=
        set EXE=
        set SAVEDIR=   

    goto execute
Trackbacks 0 : Comments 0